SQL Lion

CREATE TABLE [dbo].[Employees](
	[EmployeeName] [varchar](50) NULL,
	[DeptName] [varchar](50) NULL
) ON [PRIMARY]

DECLARE  @emptemp  TABLE
(
	[EmployeeName]  varchar(50)
	,[DeptName] varchar(50)
)
 
DECLARE @dept int
DECLARE @employee int
SET @dept = 65
SET @employee = 70
 
WHILE @dept < 70
BEGIN
	WHILE @employee < 90
	BEGIN
		INSERT INTO @emptemp
				   ([EmployeeName]
				   ,[DeptName])
			 VALUES( CHAR(@employee), CHAR(@dept) + CHAR(@dept + 1) )
 
		SET @employee = @employee + 1
	END 
 
	SET @employee = 70
	SET @dept = @dept + 1
END   
 
INSERT INTO [dbo].[Employees]
           ([EmployeeName]
           ,[DeptName])
   SELECT [EmployeeName]
           ,[DeptName] from @emptemp
 
select * FROM dbo.Employees

/*
The below script will show random 10 records from each department from Employees table.
*/
 
DECLARE @deptColumn varchar(50)
--For creation of a temporary table with no data.
select * into #temporaryT
from dbo.Employees where 1=2
 
DECLARE UserCursor CURSOR for
select distinct DeptName from dbo.Employees
 
OPEN UserCursor
FETCH NEXT FROM UserCursor
INTO @deptColumn
 
WHILE @@FETCH_STATUS = 0
BEGIN
 
	INSERT INTO #temporaryT
	select top 10 * from dbo.Employees where DeptName = @deptColumn
		order by NEWID()  --newid() for random records
 
	FETCH NEXT FROM UserCursor
	INTO @deptColumn
END
 
CLOSE UserCursor
DEALLOCATE UserCursor
 
select * from #temporaryT order by DeptName
DROP TABLE #temporaryT

SELECT DeptName,EmployeeName  FROM
(select
ROW_NUMBER() OVER(PARTITION BY DeptName ORDER BY newid() ) AS RowID
, * FROM dbo.Employees ) InnerQ
WHERE InnerQ.RowID <= 10
--RANK() can also be used instead of ROW_NUMBER()

with distinctDepts as
(SELECT DISTINCT DeptName FROM dbo.Employees)
 
SELECT InnerQ.* FROM distinctDepts  d
CROSS APPLY
(SELECT top 10 * FROM dbo.Employees
	WHERE DeptName = d.DeptName
ORDER BY newid()) InnerQ